Comment utiliser la fonction FILTRE dans Excel pour automatiser l’analyse de vos données ?
La fonction FILTRE d'Excel permet d’extraire des données d’un tableau en fonction de critères définis. Disponible uniquement sur Microsoft 365, Excel pour le Web et Excel 2021, elle offre une alternative dynamique aux filtres classiques, évitant ainsi les manipulations manuelles répétitives.
Dans cet article, nous allons voir comment utiliser la fonction FILTRE efficacement, avec des exemples concrets et des applications avancées adaptées aux besoins des professionnels.
Qu'est-ce que la fonction FILTRE dans Excel ?
La fonction FILTRE permet de filtrer dynamiquement un tableau de données en fonction de critères précis.
Contrairement aux filtres traditionnels, elle s’adapte automatiquement aux modifications des données sans avoir besoin d'actualiser manuellement ou de réappliquer les filtres à chaque manipulation.
💡 Pourquoi utiliser FILTRE ?
- Automatiser le filtrage des données en fonction de critères prédéfinis
- Gagner du temps en évitant les filtres manuels et les copier-coller
- Créer des tableaux interactifs qui se mettent à jour en temps réel
- Simplifier l’analyse des données sans VBA ni macros
Syntaxe de la fonction FILTRE
La fonction FILTRE s’utilise avec les paramètres (arguments) suivants :
=FILTRE(tableau; critère; [si_vide])
- tableau : la plage de données à filtrer
- critère : la condition à appliquer pour le filtrage
- [si_vide] (facultatif) : la valeur à afficher si aucun résultat ne correspond au critère
Attention, si aucune donnée ne correspond et que l’argument [si_vide] n’est pas renseigné, Excel affichera une erreur (#CALC!).
Exemples pratiques d'utilisation de FILTRE
1) Exemple : filtrer une colonne selon une condition
=FILTRE(C3:C10; E3:E10>200)
Affiche uniquement les valeurs de la colonne C lorsque la colonne E est supérieure à 200. On ne récupère que la liste de la colonne C et pas les valeurs de la colonne B, même si elle est utilisée comme critère de filtre !
2) Filtrer un tableau entier en fonction d’une condition
=FILTRE(C3:F10; F3:F10="Oui")
Renvoie toutes les lignes du tableau lorsque la colonne F contient "Oui" :
3) Filtrer avec plusieurs conditions (ET logique)
Pour filtrer avec plusieurs conditions en simultané, on utilise l'opérateur * qui correspond à mettre "et" entre les conditions. Par exemple :
=FILTRE(C3:F10; (E3:E10>200)*(F3:F10="Oui"))
Affiche uniquement les lignes où le cours est supérieur à 200 € ET où la colonne "Acheter ?" contient "Oui" :
4) Filtrer avec plusieurs conditions (OU logique)
De la même manière, pour cumuler plusieurs conditions mais avec "OU" et pas "ET" (soit la première condition est vraie, soit la deuxième, soit les deux), la formule est identique mais en utilisant l'opérateur "+" :
=FILTRE(C3:F10; (E3:E10>200)+(F3:F10="Oui"))
On récupère ici toutes les lignes pour lesquelles le cours est supérieur à 200 € ou bien la colonne "Acheter ?" est à "Oui", ou les deux :
5) Gérer l’absence de résultats avec l’argument [si_vide]
Si le filtre ne renvoie aucune donnée car les conditions ne sont pas respectées, on peut ajouter un argument qui écrit quelque chose par défaut, plutôt qu'afficher une erreur :
=FILTRE(C3:F10; (E3:E10>1000)*(F3:F10="Oui"); "Aucune action concernée")
Ici, il n'y a que l'action Hermès qui a un cours supérieur à 1 000 €, mais la colonne "Acheter" est à "Non", donc on n'a aucune ligne à renvoyer :
Applications avancées avec FILTRE
Combiner FILTRE avec TRIER pour un affichage ordonné
=TRIER(FILTRE(C3:F10; E3:E10>300; "Aucune action concernée");3;-1)
Ici, on récupère les actions dont le cours est >300€, triée par ordre décroissant du cours :
Associer FILTRE avec UNIQUE pour éliminer les doublons
=UNIQUE(FILTRE(A2:A20; B2:B20>1000))
✅ Affiche uniquement les valeurs uniques de la colonne A pour lesquelles B > 1000.
📌 Cas d’utilisation : identifier les clients ayant dépassé un seuil de facturation.
FAQ : questions fréquentes sur la fonction FILTRE dans Excel
Q : je ne trouve pas la fonction FILTRE dans mon Excel, est-elle disponible sur toutes les versions d’Excel ?
R : Non, la fonction FILTRE n'est disponible que sur Excel 2021, Excel Web et Microsoft 365.
Q : puis-je filtrer sur plusieurs colonnes sans afficher toutes les données (pas toutes les colonnes) ?
R : Oui, il suffit d’indiquer les colonnes souhaitées en sortie, par exemple ici on n'affiche que les colonnes A et B même si le tableau s'étend sur les colonnes suivantes :
=FILTRE(A2:B20; C2:C20="Validé")
Q : comment éviter les erreurs si aucun résultat ne correspond ?
R : la fonction FILTRE est bien faite, il suffit d'utiliser le 3e argument ( [si_vide] ) :
=FILTRE(A2:D20; C2:C20="Validé"; "Aucune donnée trouvée")
Erreurs fréquentes avec FILTRE et comment les corriger
❌ Erreur #CALC! : cela signifie qu’aucune donnée ne correspond à vos critères.
Solution : ajoutez le 3e argument si_vide pour éviter cette erreur et afficher une valeur par défaut à la place.
❌ Mauvais nombre de lignes ou colonnes en sortie : cela arrive lorsque les plages utilisées dans le critère et dans la sortie n'ont pas la même taille.
Solution : vérifiez que les dimensions (la taille) des plages sont identiques, c'est une erreur très courante et relativement simple à corriger !