La fonction FILTRE d'Excel permet d’extraire des données d’un tableau en fonction de critères définis. Disponible uniquement sur Microsoft 365, Excel pour le Web et Excel 2021, elle offre une alternative dynamique aux filtres classiques, évitant ainsi les manipulations manuelles répétitives.

La fonction FILTRE (FILTER en anglais) permet de filtrer dynamiquement un tableau de données en fonction de critères précis.

Contrairement aux filtres traditionnels, elle s’adapte automatiquement aux modifications des données sans avoir besoin d'actualiser manuellement ou de réappliquer les filtres à chaque manipulation.

💡 Pourquoi utiliser FILTRE ?

• Automatiser le filtrage des données en fonction de critères prédéfinis
• Gagner du temps en évitant les filtres manuels et les copier-coller
• Créer des tableaux interactifs qui se mettent à jour en temps réel
• Simplifier l’analyse des données sans VBA ni macros

Attention, si aucune donnée ne correspond et que l’argument [si_vide] n’est pas renseigné, Excel affichera une erreur (#CALC!).

La fonction FILTRE permet d’extraire une partie d’un tableau selon un ou plusieurs critères définis. C’est l’une des fonctions à propagation les plus puissantes d’Excel.

Voici sa structure :

=FILTRE(tableau; critère; [si_vide])

• tableau : la plage de données à filtrer
• critère : la condition à appliquer (vrai/faux)
• [si_vide] (facultatif) : la valeur à afficher si aucun résultat ne correspond

Dans les versions Excel en anglais, la fonction porte le nom FILTER avec exactement la même structure :

=FILTER(array; include; [if_empty])

Bon à savoir : FILTRE (FILTER) est une fonction à propagation. Elle renvoie plusieurs cellules à la fois, appelées plage propagée (ou spilled range). Si une cellule en aval de la formule contient déjà une valeur, FILTRE retournera l’erreur #PROPAGATION!.

1) Exemple : filtrer une colonne selon une condition

=FILTRE(C3:C10; E3:E10>200)

Affiche uniquement les valeurs de la colonne C lorsque la colonne E est supérieure à 200. On ne récupère que la liste de la colonne C et pas les valeurs de la colonne B, même si elle est utilisée comme critère de filtre !

2) Filtrer un tableau entier en fonction d’une condition

=FILTRE(C3:F10; F3:F10="Oui")

Renvoie toutes les lignes du tableau lorsque la colonne F contient "Oui" :

3) Filtrer avec plusieurs conditions (ET logique)

Pour filtrer avec plusieurs conditions en simultané, on utilise l'opérateur * qui correspond à mettre "et" entre les conditions. Par exemple :

=FILTRE(C3:F10; (E3:E10>200)*(F3:F10="Oui"))

Affiche uniquement les lignes où le cours est supérieur à 200 €  ET où la colonne "Acheter ?" contient "Oui" :

4) Filtrer avec plusieurs conditions (OU logique)

De la même manière, pour cumuler plusieurs conditions mais avec "OU" et pas "ET" (soit la première condition est vraie, soit la deuxième, soit les deux), la formule est identique mais en utilisant l'opérateur "+" :

=FILTRE(C3:F10; (E3:E10>200)+(F3:F10="Oui"))

On récupère ici toutes les lignes pour lesquelles le cours est supérieur à 200 € ou bien la colonne "Acheter ?" est à "Oui", ou les deux :

5) Gérer l’absence de résultats avec l’argument [si_vide]

Si le filtre ne renvoie aucune donnée car les conditions ne sont pas respectées, on peut ajouter un argument qui écrit quelque chose par défaut, plutôt qu'afficher une erreur :

=FILTRE(C3:F10; (E3:E10>1000)*(F3:F10="Oui"); "Aucune action concernée")

Ici, il n'y a que l'action Hermès qui a un cours supérieur à 1 000 €, mais la colonne "Acheter" est à "Non", donc on n'a aucune ligne à renvoyer :

La vraie puissance de FILTRE apparaît lorsqu’on l’imbrique dans d’autres fonctions à propagation comme TRIER ou UNIQUE. Cette composition permet de produire un rapport prêt à l’emploi en une seule formule, qui se recalcule automatiquement à chaque modification du tableau source. Pour la documentation officielle Microsoft sur la fonction FILTRE (FILTER en anglais), consultez le guide FILTRE de Microsoft Learn.

Combiner FILTRE avec TRIER pour un affichage ordonné

=TRIER(FILTRE(C3:F10; E3:E10>300; "Aucune action concernée");3;-1)

Ici, on récupère les actions dont le cours est >300 €, triée par ordre décroissant du cours :

Associer FILTRE avec UNIQUE pour éliminer les doublons

=UNIQUE(FILTRE(A2:A20; B2:B20>1000))

✅ Affiche uniquement les valeurs uniques de la colonne A pour lesquelles B > 1000.

📌 Cas d’utilisation : identifier les clients ayant dépassé un seuil de facturation, ou consolider une liste de fournisseurs distincts au-dessus d’un seuil d’achat. La même logique en anglais : =UNIQUE(FILTER(A2:A20; B2:B20>1000)).

La fonction FILTRE (FILTER en version anglaise d’Excel) est apparue avec les fonctions à propagation sur Excel 365 et Excel 2021. Si vous obtenez l'erreur #NOM? ou si la fonction n'apparait pas dans l'auto-complétion, votre version d'Excel ne la prend pas en charge.